/****************************************************************************/
/*	Copyright (c) 2009, Bendor Research Pty. Ltd. All rights reserved.		*/
/*	This software is released under the GNU General Public License, version	*/
/*	3, with the exemptions that 1) the header files installed by this 	 	*/
/*	package can be included in closed-source code and 2) the libraries		*/
/*	built by this package can be statically linked into a closed-source 	*/
/*	binary. See the file LICENSE for the details.							*/
/*	This software is provided "AS IS", without any warranty or guarantee.	*/
/*	By using this software you acknowledge that neither Bendor Research nor	*/
/*	any of its personnel or affiliates can be held liable for any damages,	*/
/*	including, but not limited to, loss of business, loss of money, loss of */
/*	life, loss of reputation, arising out of this software being faulty or	*/
/*	not performing as advertised, even if Bendor Research was aware of such	*/
/*	faults in the software. You use this software at your own risk, any and */
/*	all liabilities that arise out of your using this software are strictly	*/
/*	yours.																	*/
/****************************************************************************/

#include <arm_func.h>

/*
*	The function returns the number of trailing 0 bits in a 32-bit word.
*
*	Algorithm:
*
*	unsigned trzcnt( unsigned x )
*	{
*	unsigned n = 0;
*
*		if ( ! ( x << 16 ) ) { n += 16; x >>= 16; }
*		if ( ! ( x << 24 ) ) { n +=  8; x >>=  8; }
*		if ( ! ( x << 28 ) ) { n +=  4; x >>=  4; }
*		if ( ! ( x << 30 ) ) { n +=  2; x >>=  2; }
*		if ( ! ( x << 31 ) ) { n +=  1; x >>=  1; }
*		if ( ! ( x << 31 ) ) n++;
*		return( n );
*	}
*/

	afunc	trzcnt
	mov		r1,#1
	movs	r2,r0,lsl #16
	addeq	r1,#16
	moveq	r0,r0,lsr #16
	movs	r2,r0,lsl #24
	addeq	r1,#8
	moveq	r0,r0,lsr #8
	movs	r2,r0,lsl #28
	addeq	r1,#4
	moveq	r0,r0,lsr #4
	movs	r2,r0,lsl #30
	addeq	r1,#2
	moveq	r0,r0,lsr #2
	movs	r2,r0,lsl #31
	addeq	r1,#1
	moveq	r0,r0,lsr #1
	and		r0,r0,#1
	sub		r0,r1,r0
	bx		lr

